sunet/scheme/httpd/surflets/web-server/root/surflets/news.scm

(define-structure servlet servlet-interface
  (open scheme-with-scsh
	servlets)
  (begin
    (define *data* '())
    
    (define (read-data)
      (let ((news-input (open-input-file "news.txt")))
	(do ((next-line (read-line news-input)
			(read-line news-input))
	     (data '() (cons next-line data)))
	    ((eof-object? next-line) 
	     (close news-input)
	     data))))
      
    (define (main req)
      (if (null? *data*) (set! *data* (read-data)))
      (let loop ((count (- (length *data*) 1)))
	(if (< count 0)
	    (show-final-page)
	    (begin
	      (show-news-page (list-ref *data* count))
	      (loop (- count 1))))))

    (define (show-final-page)
      (send-html/finish 
       `(html (body (p (h1 "THAT'S IT"))
		    (p ("That's it..."))
		    (hr)
		    (p (URL "news.scm" "See news again.") (br)
		       (URL "/" "Return to main menu."))))))

    (define (show-news-page news)
      (send-html/suspend 
       (lambda (next-url)
	 `(html (body (p (h1 ,news))
		      (a (@ href ,next-url) "read more...")
		      (hr)
		      (p (URL "news.scm" "See news again from beginning.") (br)
			 (URL "/" "Return to main menu.")))))))
    ))